event.load
      extern.close("{APP_NAME}") // Only one instance allowed
      app.init("{APP_ID}", "{APP_NAME}", "{APP_VERSION}", "{APP_BUILD}", "{CREATE_LOG}")  

      system.priority(low)
      window.main.pos.now(screen.width() - 200, 40,196,189)
      window.main.transparency(null,0) // Alpha = 0, window is hidden
      window.main.canGoOut(true)

      window.main.shape.load(path.rsc("face.bmp"))
      &Back = draw.mem.createFromFile(path.rsc("face.bmp"))
      &Zoom = 100
      doEvent.clock_timer()
event.end

event.clock_timer
      if(mouse.main.isOverWindow() = true)
            var.dec(zoom, 10, 100, 100)
      if.else      
            var.inc(zoom, 1, 150, 150)
      if.end
      
      draw.main.rect(0,0,100,100,14221056)

      &curW = p100(98)
      &curH = p100(93)
      draw.main.copyFrom.&Back(0, 0, 98, 93, 49-&curW/2, 46-&curH/2, &curW, &curH)
      window.main.shape.from.main(0,0,98,93)

      // Seconds
      &aSec = time.second() * 6 - 90
      draw.main.line(50, 50, num.cos(&aSec, p100(45))+50, num.sin(&aSec, p100(45))+50, p100(2), num.rgb(255,120,0))

      // Hours
      &aHour = time.hour()
      &aHour = ?(&aHour > 12, (&aHour - 12)  , &aHour) * 30 - 90
      &aHour = &aHour + time.minute()/2
      draw.main.line(50, 50, num.cos(&aHour, p100(30))+50, num.sin(&aHour, p100(30))+50, p100(6), num.rgb(0,150,255))

      // Minutes
      &aMin = time.minute() * 6 - 90
      draw.main.line(50, 50, num.cos(&aMin, p100(40))+50, num.sin(&aMin, p100(40))+50, p100(3), num.rgb(0,150,255))


      draw.main.paint()
      window.main.transparency(null,280 - &zoom)
      doEvent.clock_timer(10)      
event.end

function.p100(&max)
      &ret = num.compute(100*&max/&zoom)
      return(?(&ret < 1, 1, &ret))
function.end